classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel virtual/kernel-${PV}"
   4 DEPENDS += "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules bluez-dtl1-workaround"
   5
   6 # we include gcc above, we dont need virtual/libc
   7 INHIBIT_DEFAULT_DEPS = "1"
   8
   9 KERNEL_IMAGETYPE ?= "zImage"
  10
  11 # Add dependency on mkimage for kernels that build a uImage
  12
  13 python __anonymous () {
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23
  24     machine_kernel_pr = bb.data.getVar('MACHINE_KERNEL_PR', d, True)
  25
  26     if machine_kernel_pr:
  27        bb.data.setVar('PR', machine_kernel_pr, d)
  28 }
  29
  30 INITRAMFS_IMAGE ?= ""
  31 INITRAMFS_TASK ?= ""
  32
  33 inherit kernel-arch
  34
  35 PACKAGES_DYNAMIC += "kernel-*"
  36 PACKAGES_DYNAMIC += "kernel-module-*"
  37 PACKAGES_DYNAMIC += "kernel-image-*"
  38 PACKAGES_DYNAMIC += "kernel-firmware-*"
  39
  40 export OS = "${TARGET_OS}"
  41 export CROSS_COMPILE = "${TARGET_PREFIX}"
  42
  43 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  44
  45 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  46
  47 KERNEL_CCSUFFIX ?= ""
  48 KERNEL_LDSUFFIX ?= ""
  49
  50 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  51 # specific options necessary for building the kernel and modules.
  52 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  53 TARGET_CC_KERNEL_ARCH ?= ""
  54 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  55 TARGET_LD_KERNEL_ARCH ?= ""
  56 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  57
  58 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  59 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  60
  61 # Where built kernel lies in the kernel tree
  62 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  63 KERNEL_IMAGEDEST = "boot"
  64
  65 #
  66 # configuration
  67 #
  68 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  69
  70 KERNEL_VERSION = "${@get_kernelversion('${B}')}"
  71 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  72
  73 KERNEL_LOCALVERSION ?= ""
  74
  75 # kernels are generally machine specific
  76 PACKAGE_ARCH = "${MACHINE_ARCH}"
  77
  78 # U-Boot support
  79 UBOOT_ENTRYPOINT ?= "20008000"
  80 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  81
  82 # For the kernel, we don't want the '-e MAKEFLAGS=' in EXTRA_OEMAKE.
  83 # We don't want to override kernel Makefile variables from the environment
  84 EXTRA_OEMAKE = ""
  85
  86 kernel_do_compile() {
  87         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  88         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  89         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  90                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  91         fi
  92         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  93 }
  94
  95 do_compile_kernelmodules() {
  96         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  97         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  98                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  99         else
 100                 oenote "no modules to compile"
 101         fi
 102 }
 103 addtask compile_kernelmodules after do_compile before do_install
 104
 105 kernel_do_install() {
 106         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 107         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 108                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 109         else
 110                 oenote "no modules to install"
 111         fi
 112
 113         install -d ${D}/${KERNEL_IMAGEDEST}
 114         install -d ${D}/boot
 115         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 116         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 117         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 118         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 119         [ -e Module.symvers ] && install -m 0644 Module.symvers ${D}/boot/Module.symvers-${KERNEL_VERSION}
 120         install -d ${D}/etc/modutils
 121         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 122                 install -d ${D}/etc/modprobe.d
 123         fi
 124
 125         # Check if scripts/genksyms exists and if so, build it
 126         if [ -e scripts/genksyms/ ]; then
 127                 oe_runmake SUBDIRS="scripts/genksyms"
 128         fi
 129
 130         # we need to set kerneldir here as some kernels have a do_install_append
 131         # which assumes kerneldir is set
 132         kerneldir=${D}/kernel/
 133 }
 134
 135 sysroot_stage_all_append() {
 136
 137         kerneldir=${SYSROOT_DESTDIR}${STAGING_KERNEL_DIR}
 138
 139         if [ -e include/asm ] ; then
 140                 # This link is generated only in kernel before 2.6.33-rc1, don't stage it for newer kernels
 141                 ASMDIR=`readlink include/asm`
 142
 143                 mkdir -p $kerneldir/include/$ASMDIR
 144                 cp -fR include/$ASMDIR/* $kerneldir/include/$ASMDIR/
 145         fi
 146
 147         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 148         if [ -e arch/${ARCH}/include/asm/ ] ; then
 149                 if [ -e include/asm ] ; then
 150                         cp -fR arch/${ARCH}/include/asm/* $kerneldir/include/$ASMDIR/
 151                 fi
 152                 install -d $kerneldir/arch/${ARCH}/include
 153                 cp -fR arch/${ARCH}/* $kerneldir/arch/${ARCH}/
 154
 155         # Check for arch/x86 on i386
 156         elif [ -d arch/x86/include/asm/ ]; then
 157                 mkdir -p $kerneldir/include/asm-x86/
 158                 cp -fR arch/x86/include/asm/* $kerneldir/include/asm-x86/
 159                 install -d $kerneldir/arch/x86/include
 160                 cp -fR arch/x86/* $kerneldir/arch/x86/
 161         fi
 162
 163         if [ -e include/asm ] ; then
 164                 rm -f $kerneldir/include/asm
 165                 ln -sf $ASMDIR $kerneldir/include/asm
 166         fi
 167
 168         mkdir -p $kerneldir/include/asm-generic
 169         cp -fR include/asm-generic/* $kerneldir/include/asm-generic/
 170
 171         for entry in drivers/crypto drivers/media include/generated include/linux include/net include/pcmcia include/media include/acpi include/sound include/video include/scsi include/trace include/mtd include/rdma include/drm include/xen crypto/ocf; do
 172                 if [ -d $entry ]; then
 173                         mkdir -p $kerneldir/$entry
 174                         cp -fR $entry/* $kerneldir/$entry/
 175                 fi
 176         done
 177         if [ -f include/Kbuild ]; then
 178                 cp -fR include/Kbuild $kerneldir/include
 179         fi
 180
 181         if [ -d drivers/sound ]; then
 182                 # 2.4 alsa needs some headers from this directory
 183                 mkdir -p $kerneldir/include/drivers/sound
 184                 cp -fR drivers/sound/*.h $kerneldir/include/drivers/sound/
 185         fi
 186
 187         install -m 0644 .config $kerneldir/config-${KERNEL_VERSION}
 188         ln -sf config-${KERNEL_VERSION} $kerneldir/.config
 189         ln -sf config-${KERNEL_VERSION} $kerneldir/kernel-config
 190         echo "${KERNEL_VERSION}" >$kerneldir/kernel-abiversion
 191         echo "${S}" >$kerneldir/kernel-source
 192         echo "${KERNEL_CCSUFFIX}" >$kerneldir/kernel-ccsuffix
 193         echo "${KERNEL_LDSUFFIX}" >$kerneldir/kernel-ldsuffix
 194         [ -e Rules.make ] && install -m 0644 Rules.make $kerneldir/
 195         [ -e Makefile ] && install -m 0644 Makefile $kerneldir/
 196
 197         # Check if arch/${ARCH}/Makefile exists and install it
 198         if [ -e arch/${ARCH}/Makefile ]; then
 199                 install -d $kerneldir/arch/${ARCH}
 200                 install -m 0644 arch/${ARCH}/Makefile* $kerneldir/arch/${ARCH}
 201         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 202         elif [ -e arch/x86/Makefile ]; then
 203                 install -d $kerneldir/arch/x86
 204                 install -m 0644 arch/x86/Makefile* $kerneldir/arch/x86
 205         fi
 206         cp -fR include/config* $kerneldir/include/
 207         # Install kernel images and system.map to staging
 208         [ -e vmlinux ] && install -m 0644 vmlinux $kerneldir/
 209         install -m 0644 ${KERNEL_OUTPUT} $kerneldir/${KERNEL_IMAGETYPE}
 210         install -m 0644 System.map $kerneldir/System.map-${KERNEL_VERSION}
 211         [ -e Module.symvers ] && install -m 0644 Module.symvers $kerneldir/
 212
 213         cp -fR scripts $kerneldir/
 214 }
 215
 216 kernel_do_configure() {
 217         yes '' | oe_runmake oldconfig
 218         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
 219                 for img in cpio.gz cpio.lzo cpio.lzma; do
 220                 if [ -e "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" ]; then
 221                         cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.$img" initramfs.$img
 222                 fi
 223                 done
 224         fi
 225 }
 226 do_configure[depends] += "${INITRAMFS_TASK}"
 227
 228 pkg_postinst_kernel () {
 229         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 230 }
 231
 232 pkg_postrm_kernel () {
 233         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 234 }
 235
 236 inherit cml1
 237
 238 EXPORT_FUNCTIONS do_compile do_install do_configure
 239
 240 # kernel-base becomes kernel-${KERNEL_VERSION}
 241 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 242 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 243 FILES = ""
 244 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 245 FILES_kernel-dev = "/boot/System.map* /boot/Module.symvers* /boot/config*"
 246 FILES_kernel-vmlinux = "/boot/vmlinux*"
 247 RDEPENDS_kernel = "kernel-base"
 248 # Allow machines to override this dependency if kernel image files are
 249 # not wanted in images as standard
 250 RDEPENDS_kernel-base ?= "kernel-image"
 251 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 252 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 253 ALLOW_EMPTY_kernel = "1"
 254 ALLOW_EMPTY_kernel-base = "1"
 255 ALLOW_EMPTY_kernel-image = "1"
 256
 257 # Userspace workarounds for kernel modules issues
 258 # This is shame, fix the kernel instead!
 259 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 260
 261 # renamed modules
 262 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 263
 264 pkg_postinst_kernel-image () {
 265 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 266         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 267 fi
 268 if [ -n "$D" ]; then
 269         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 270 else
 271         depmod -a ${KERNEL_VERSION}
 272 fi
 273 }
 274
 275 pkg_postinst_modules () {
 276 if [ -n "$D" ]; then
 277         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 278 else
 279         depmod -a ${KERNEL_VERSION}
 280         update-modules || true
 281 fi
 282 }
 283
 284 pkg_postrm_modules () {
 285 update-modules || true
 286 }
 287
 288 autoload_postinst_fragment() {
 289 if [ x"$D" = "x" ]; then
 290         modprobe %s || true
 291 fi
 292 }
 293
 294 # autoload defaults (alphabetically sorted)
 295 module_autoload_hidp = "hidp"
 296 module_autoload_ipv6 = "ipv6"
 297 module_autoload_ipsec = "ipsec"
 298 module_autoload_ircomm-tty = "ircomm-tty"
 299 module_autoload_rfcomm = "rfcomm"
 300 module_autoload_sa1100-rtc = "sa1100-rtc"
 301 # sa1100-rtc was renamed in 2.6.23 onwards
 302 module_autoload_rtc-sa1100 = "rtc-sa1100"
 303
 304 # alias defaults (alphabetically sorted)
 305 module_conf_af_packet = "alias net-pf-17 af_packet"
 306 module_conf_bluez = "alias net-pf-31 bluez"
 307 module_conf_bnep = "alias bt-proto-4 bnep"
 308 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 309 module_conf_l2cap = "alias bt-proto-0 l2cap"
 310 module_conf_sco = "alias bt-proto-2 sco"
 311 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 312
 313 python populate_packages_prepend () {
 314         import os
 315         def extract_modinfo(file):
 316                 import tempfile, re
 317                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 318                 tf = tempfile.mkstemp()
 319                 tmpfile = tf[1]
 320                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 321                 os.system(cmd)
 322                 f = open(tmpfile)
 323                 l = f.read().split("\000")
 324                 f.close()
 325                 os.close(tf[0])
 326                 os.unlink(tmpfile)
 327                 exp = re.compile("([^=]+)=(.*)")
 328                 vals = {}
 329                 for i in l:
 330                         m = exp.match(i)
 331                         if not m:
 332                                 continue
 333                         vals[m.group(1)] = m.group(2)
 334                 return vals
 335
 336         def parse_depmod():
 337                 import re
 338
 339                 dvar = bb.data.getVar('PKGD', d, 1)
 340                 if not dvar:
 341                         bb.error("PKGD not defined")
 342                         return
 343
 344                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 345                 kernelver_stripped = kernelver
 346                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 347                 if m:
 348                         kernelver_stripped = m.group(1)
 349                 path = bb.data.getVar("PATH", d, 1)
 350                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 351                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 352
 353                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 354                 f = os.popen(cmd, 'r')
 355
 356                 deps = {}
 357                 pattern0 = "^(.*\.k?o):..*$"
 358                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 359                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 360                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 361                 pattern4 = "^\t(.*\.k?o)\s*$"
 362
 363                 line = f.readline()
 364                 while line:
 365                         if not re.match(pattern0, line):
 366                                 line = f.readline()
 367                                 continue
 368                         m1 = re.match(pattern1, line)
 369                         if m1:
 370                                 deps[m1.group(1)] = m1.group(2).split()
 371                         else:
 372                                 m2 = re.match(pattern2, line)
 373                                 if m2:
 374                                         deps[m2.group(1)] = m2.group(2).split()
 375                                         line = f.readline()
 376                                         m3 = re.match(pattern3, line)
 377                                         while m3:
 378                                                 deps[m2.group(1)].extend(m3.group(1).split())
 379                                                 line = f.readline()
 380                                                 m3 = re.match(pattern3, line)
 381                                         m4 = re.match(pattern4, line)
 382                                         deps[m2.group(1)].extend(m4.group(1).split())
 383                         line = f.readline()
 384                 f.close()
 385                 return deps
 386
 387         def get_dependencies(file, pattern, format):
 388                 prefix = os.path.normpath(os.path.join(
 389                         os.path.join(bb.data.getVar('PKGD', d, 1) or ''),
 390                         'lib/modules',
 391                         bb.data.getVar('KERNEL_VERSION', d, 1)
 392                 )) + '/'
 393                 file = file.replace(prefix, '', 1)
 394
 395                 if module_deps.has_key(file):
 396                         import re
 397                         dependencies = []
 398                         for i in module_deps[file]:
 399                                 m = re.match(pattern, os.path.basename(i))
 400                                 if not m:
 401                                         continue
 402                                 on = legitimize_package_name(m.group(1))
 403                                 dependency_pkg = format % on
 404                                 dependencies.append(dependency_pkg)
 405                         return dependencies
 406                 return []
 407
 408         def frob_metadata(file, pkg, pattern, format, basename):
 409                 import re
 410                 vals = extract_modinfo(file)
 411
 412                 dvar = bb.data.getVar('PKGD', d, 1)
 413
 414                 # If autoloading is requested, output /etc/modutils/<name> and append
 415                 # appropriate modprobe commands to the postinst
 416                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 417                 if not autoload:
 418                     # Also, try canonical name with dashes
 419                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 420                 if autoload:
 421                         name = '%s/etc/modutils/%s' % (dvar, basename)
 422                         f = open(name, 'w')
 423                         for m in autoload.split():
 424                                 f.write('%s\n' % m)
 425                         f.close()
 426                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 427                         if not postinst:
 428                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 429                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 430                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 431
 432                 # Write out any modconf fragment
 433                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 434                 if modconf:
 435                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 436                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 437                         else:
 438                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 439                         f = open(name, 'w')
 440                         f.write("%s\n" % modconf)
 441                         f.close()
 442
 443                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 444                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 445                 bb.data.setVar('FILES_%s' % pkg, files, d)
 446
 447                 if vals.has_key("description"):
 448                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 449                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 450
 451                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 452                 if rdepends_str:
 453                         rdepends = rdepends_str.split()
 454                 else:
 455                         rdepends = []
 456                 rdepends.extend(get_dependencies(file, pattern, format))
 457                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 458
 459         module_deps = parse_depmod()
 460         module_regex = '^(.*)\.k?o$'
 461         module_pattern = 'kernel-module-%s'
 462
 463         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 464         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 465
 466         maybe_update_modules = "update-modules "
 467         if bb.data.getVar("ONLINE_PACKAGE_MANAGEMENT", d) == "none":
 468                 maybe_update_modules = ""
 469
 470         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 471         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 472         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='%skernel-%s' % (maybe_update_modules, bb.data.getVar("KERNEL_VERSION", d, 1)))
 473
 474         import re
 475         metapkg = "kernel-modules"
 476         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 477         bb.data.setVar('FILES_' + metapkg, "", d)
 478         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 479         depchains = (d.getVar("DEPCHAIN_POST", True) or "").split()
 480         for l in module_deps.values():
 481                 for i in l:
 482                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 483                         blacklist.append(pkg)
 484         metapkg_rrecommends = []
 485         packages = bb.data.getVar('PACKAGES', d, 1).split()
 486         for pkg in packages[1:]:
 487                 if not pkg in blacklist and not pkg in metapkg_rrecommends and not any(pkg.endswith(post) for post in depchains):
 488                         metapkg_rrecommends.append(pkg)
 489         bb.data.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rrecommends), d)
 490         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 491         packages.append(metapkg)
 492         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 493 }
 494
 495 # Support checking the kernel size since some kernels need to reside in partitions
 496 # with a fixed length or there is a limit in transferring the kernel to memory
 497 do_sizecheck() {
 498         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" ]; then
 499                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 500                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 501                         rm ${KERNEL_OUTPUT}
 502                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 503                 fi
 504         fi
 505 }
 506
 507 addtask sizecheck before do_install after do_compile
 508
 509 do_uboot_mkimage() {
 510     if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 511         ENTRYPOINT=${UBOOT_ENTRYPOINT}
 512         if test -n "${UBOOT_ENTRYSYMBOL}"; then
 513             ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
 514                    awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
 515         fi
 516         if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 517             ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 518             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
 519             rm -f linux.bin
 520         else
 521             ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 522             rm -f linux.bin.gz
 523             gzip -9 linux.bin
 524             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
 525             rm -f linux.bin.gz
 526         fi
 527     fi
 528 }
 529
 530 addtask uboot_mkimage before do_install after do_compile
 531
 532 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 533 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 534 MODULES_IMAGE_BASE_NAME ?= modules-${PV}-${PR}-${MACHINE}
 535
 536 do_deploy() {
 537         install -d ${DEPLOY_DIR_IMAGE}
 538         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 539         package_stagefile_shell ${S}/${KERNEL_OUTPUT}
 540         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 541
 542         if [ -d "${PKGD}/lib" ]; then
 543                 fakeroot tar -cvzf ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz -C ${PKGD} lib
 544                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${MODULES_IMAGE_BASE_NAME}.tgz
 545         fi
 546
 547         cd ${DEPLOY_DIR_IMAGE}
 548         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 549         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 550         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 551 }
 552
 553 do_deploy[dirs] = "${S}"
 554 do_deploy[depends] += "fakeroot-native:do_populate_sysroot"
 555
 556 addtask deploy before do_build after do_package